软件
产品
前面讲述了ansa如何建模及网格划分最终导出可以用于计算的cdb文件，那么这一节大致来说下ansys计算的问题。
1 ansys操作，以第二节锚固模型为例计算钢锚箱的受力情况， 边界 条件为节段模型两端面固结，然后锚固上锚垫板承力的范围上加索力（索力转换成面荷载或者点荷载）。
具体命令流如下：
finish
/clear
!读入模型及填入数据
/INPUT,'000','cdb',,, 0 !000是我保存的这个cdb文件的名称。
/prep7
!一端固接
allsel
nsel,s,loc,z,-1000,600 !选取节段模型的两端面全部固结，如果横桥向只建了一半，那么还要在这个断面要加对称边界。
d,all,ux
d,all,uy
d,all,uz
!另一端固接
allsel
nsel,s,loc,z,-32900,-31000
d,all,ux
d,all,uy
d,all,uz
FINISH
/solu
!!!!替代方式的意思是如果前面荷载某个自由度处有荷载，而本步又在此自由度处施加了荷载，则后面的替代前面的
!!!1采用缺省时，对同一自由度处的荷载，后面施加的荷载替代了前面施加的荷载，采用累加时施加的所有荷载都在本步有效
SFCUM,Pres,ADD !由于ansys缺省的荷载处理方式是替代方式repl，add是累加，igno是忽略
dcum,add !累加节点自由度约束，自由度节点约束为累加方式
sfcum,all,add
time,1
allsel,all
CS,20,0,26833,33330,33343 !根据已有的三个节点定义局部坐标系。
CSYS,0
!对锚固节点施加1300t的力,分力的正负根据模型中的锚固装置方向判定
allsel,all
esel,s,type,,945 !锚固垫板号，这个在ansa中找到PID的编号。
nsle,r !选择单元上的所有节点
CSYS,20 !在当前20号坐标系下操作，是为了把这部分点选出来才建的局部坐标系。
nsel,r,loc,z,-2,2
* get ,nnum,node,,count !返回节点的数目
CSYS,0 !回到0号坐标系下操作
f,all,fx,1055238.492/nnum !x方向上的分力
f,all,fy,8222687.925/nnum !y方向上的分力
f,all,fz,-4257576.22/nnum !z方向上的分力
allsel
solve
finish
2 查看结果，也就是后处理部分。
!!!!后处理
!!!!!!!!!!!!!!!!查看锚箱及节点板部分的应力!!!!!!!!!!!!!!!!
/post1
allsel,all
esel,s,type,,945,948 !查看要分析的板号，这个在ansa中找到PID的编号。
esel,a,type,,1070,1072
esel,a,type,,1075,1081
nsle,r
/DSCALE,ALL,OFF !关闭显示变形
/EFACET,1
plnsol,s,eqv !显示节点等效应力
esel,r,p !需要在界面中框选单元
!!!!!!!!!!!!!!!!保存当前窗口为图片!!!!!!!!!!!!!!!!
/REPLOT
/SHOW,CLOSE
/DEVICE, VECTOR ,0
!*
/SHOW,JPEG,,0
JPEG,QUAL,100,
JPEG,ORIENT,HORIZ
JPEG,COLOR,2
JPEG,TMOD,1
/GFILE,800,
!*
/CMAP,_TEMPCMAP_,CMP,,SAVE
/RGB,INDEX,100,100,100,0
/RGB,INDEX,0,0,0,15
/REPLOT
/CMAP,_TEMPCMAP_,CMP
/DELETE,_TEMPCMAP_,CMP
/SHOW,CLOSE
/DEVICE,VECTOR,0
!*
免责声明：本文系网络转载或改编，未找到原创作者，版权归原作者所有。如涉及版权，请联系删
技术文档
热门文章
155-2731-8020
