许可优化
许可优化
产品
产品
解决方案
解决方案
服务支持
服务支持
关于
关于
软件库
当前位置:服务支持 >  软件文章 >  Unity Shader极光效果代码分享,天空盒特效制作

Unity Shader极光效果代码分享,天空盒特效制作

阅读数 13
点赞 0
article_banner


Shader "Skybox/Aurora"

{

 Properties

 {

   _TimeScale("Time Scale", Float) = 1.0

   _Exposure("Exposure", Range(0.5, 3.0)) = 1.8

   _StarIntensity("Star Intensity", Range(0, 2)) = 1.0

   _AuroraHeight("Aurora Height", Range(-2, 2)) = 0.8

 }

   SubShader

 {

   Tags { "Queue" = "Background" "RenderType" = "Background" "PreviewType" = "Skybox" }

   Cull Off

   ZWrite Off

   Pass

   {

     CGPROGRAM

     #pragma vertex vert

     #pragma fragment frag

     #pragma target 3.0

     #include "UnityCG.cginc"

     float _TimeScale;

     float _Exposure;

     float _StarIntensity;

     float _AuroraHeight;

     struct appdata

     {

       float4 vertex : POSITION;

       float3 texcoord : TEXCOORD0;

     };

     struct v2f

     {

       float4 pos : SV_POSITION;

       float3 viewDir : TEXCOORD0;

       float4 screenPos : TEXCOORD1;

     };

     float2x2 mm2(float a)

     {

       float c = cos(a);

       float s = sin(a);

       return float2x2(c, s, -s, c);

     }

     static float2x2 m2 = float2x2(0.95534, 0.29552, -0.29552, 0.95534);

     float tri(float x)

     {

       return clamp(abs(frac(x) - 0.5), 0.01, 0.49);

     }

     float2 tri2(float2 p)

     {

       return float2(tri(p.x) + tri(p.y), tri(p.y + tri(p.x)));

     }

     float triNoise2d(float2 p, float spd)

     {

       float time = _Time.y * _TimeScale;

       float z = 1.8;

       float z2 = 2.5;

       float rz = 0.0;

       p = mul(mm2(p.x * 0.06), p);

       float2 bp = p;

       for (float i = 0.0; i < 5.0; i++)

       {

         float2 dg = tri2(bp * 1.85) * 0.75;

         dg = mul(mm2(time * spd), dg);

         p -= dg / z2;

         bp *= 1.3;

         z2 *= 0.45;

         z *= 0.42;

         p *= 1.21 + (rz - 1.0) * 0.02;

         rz += tri(p.x + tri(p.y)) * z;

         p = mul(-m2, p);

       }

       return clamp(1.0 / pow(rz * 29.0, 1.3), 0.0, 0.55);

     }

     float hash21(float2 n)

     {

       return frac(sin(dot(n, float2(12.9898, 4.1414))) * 43758.5453);

     }

     float4 aurora(float3 ro, float3 rd)

     {

       float4 col = float4(0, 0, 0, 0);

       float4 avgCol = float4(0, 0, 0, 0);

       for (float i = 0.0; i < 50.0; i++)

       {

         float of = 0.006 * hash21(float2(i, i * 2.0)) * smoothstep(0.0, 15.0, i);

         float pt = ((_AuroraHeight + pow(i, 1.4) * 0.002) - ro.y) / (rd.y * 2.0 + 0.4);

         pt -= of;

         float3 bpos = ro + pt * rd;

         float2 p = bpos.xz;

         float rzt = triNoise2d(p, 0.06);

         float4 col2 = float4(0, 0, 0, rzt);

         col2.rgb = (sin(1.0 - float3(2.15, -0.5, 1.2) + i * 0.043) * 0.5 + 0.5) * rzt;

         avgCol = lerp(avgCol, col2, 0.5);

         col += avgCol * exp2(-i * 0.065 - 2.5) * smoothstep(0.0, 5.0, i);

       }

       col *= clamp(rd.y * 15.0 + 0.4, 0.0, 1.0);

       return col * _Exposure;

     }

     float3 nmzHash33(float3 q)

     {

       uint3 p = uint3(int3(q));

       p = p * uint3(374761393U, 1103515245U, 668265263U) + p.zxy + p.yzx;

       p = p.yzx * (p.zxy ^ (p >> 3U));

       return float3(p ^ (p >> 16U)) * (1.0 / float(0xffffffffU));

     }

     float3 stars(float3 p)

     {

       float3 c = float3(0, 0, 0);

       float res = 1024.0;

       for (float i = 0.0; i < 4.0; i++)

       {

         float3 q = frac(p * (0.15 * res)) - 0.5;

         float3 id = floor(p * (0.15 * res));

         float2 rn = nmzHash33(id).xy;

         float c2 = 1.0 - smoothstep(0.0, 0.6, length(q));

         c2 *= step(rn.x, 0.0005 + i * i * 0.001);

         c += c2 * (lerp(float3(1.0, 0.49, 0.1), float3(0.75, 0.9, 1.0), rn.y) * 0.1 + 0.9);

         p *= 1.3;

       }

       return c * c * 0.8 * _StarIntensity;

     }

     float3 bg(float3 rd)

     {

       float sd = dot(normalize(float3(-0.5, -0.6, 0.9)), rd) * 0.5 + 0.5;

       sd = pow(sd, 5.0);

       float3 col = lerp(float3(0.05, 0.1, 0.2), float3(0.1, 0.05, 0.2), sd);

       return col * 0.63;

     }

     v2f vert(appdata v)

     {

       v2f o;

       o.pos = UnityObjectToClipPos(v.vertex);

       o.viewDir = v.texcoord;

       o.screenPos = ComputeScreenPos(o.pos);

       return o;

     }

     float4 frag(v2f i) : SV_Target

     {

       float3 rd = normalize(i.viewDir);

       float3 ro = float3(0, 0, -6.7);

       float3 col = float3(0, 0, 0);

       float3 brd = rd;

       float fade = smoothstep(0.0, 0.01, abs(brd.y)) * 0.1 + 0.9;

       col = bg(rd) * fade;

       if (rd.y > 0)

       {

         float4 aur = smoothstep(0.0, 1.5, aurora(ro, rd)) * fade;

         col += stars(rd);

         col = col * (1.0 - aur.a) + aur.rgb;

       }

       else // Reflections

       {

         rd.y = abs(rd.y);

         col = bg(rd) * fade * 0.6;

         float4 aur = smoothstep(0.0, 2.5, aurora(ro, rd));

         col += stars(rd) * 0.1;

         col = col * (1.0 - aur.a) + aur.rgb;

         float3 pos = ro + ((0.5 - ro.y) / rd.y) * rd;

         float nz2 = triNoise2d(pos.xz * float2(0.5, 0.7), 0.0);

         col += lerp(float3(0.2, 0.25, 0.5) * 0.08, float3(0.3, 0.3, 0.5) * 0.7, nz2 * 0.4);

       }

       return float4(col, 1.0);

     }

     ENDCG

   }

 }

   FallBack Off

}

 


免责声明:本文系网络转载或改编,未找到原创作者,版权归原作者所有。如涉及版权,请联系删

相关文章
技术文档
QR Code
微信扫一扫,欢迎咨询~
customer

online

联系我们
武汉格发信息技术有限公司
湖北省武汉市经开区科技园西路6号103孵化器
电话:155-2731-8020 座机:027-59821821
邮件:tanzw@gofarlic.com
Copyright © 2023 Gofarsoft Co.,Ltd. 保留所有权利
遇到许可问题?该如何解决!?
评估许可证实际采购量? 
不清楚软件许可证使用数据? 
收到软件厂商律师函!?  
想要少购买点许可证,节省费用? 
收到软件厂商侵权通告!?  
有正版license,但许可证不够用,需要新购? 
联系方式 board-phone 155-2731-8020
close1
预留信息,一起解决您的问题
* 姓名:
* 手机:

* 公司名称:

姓名不为空

姓名不为空

姓名不为空
手机不正确

手机不正确

手机不正确
公司不为空

公司不为空

公司不为空